#lang sicp

(define (make-leaf symbol weight) (list 'leaf symbol weight))
(define (leaf? object) (eq? (car object) 'leaf))
(define (symbol-leaf x) (cadr x))
(define (weight-leaf x) (caddr x))

(define (make-code-tree left right)
  (list left
        right
        (append (symbols left) (symbols right))
        (+ (weight left) (weight right))))

(define (left-branch tree) (car tree))
(define (right-branch tree) (cadr tree))
(define (symbols tree)
  (if (leaf? tree)
      (list (symbol-leaf tree))
      (caddr tree)))
(define (weight tree)
  (if (leaf? tree)
      (weight-leaf tree)
      (cadddr tree)))

(define (decode bits tree)
  (define (decode-1 bits current-branch)
    (if (null? bits)
        '()
        (let ((next-branch
               (choose-branch (car bits) current-branch)))
          (if (leaf? next-branch)
              (cons (symbol-leaf next-branch)
                    (decode-1 (cdr bits) tree))
              (decode-1 (cdr bits) next-branch)))))
  (decode-1 bits tree))

(define (choose-branch bit branch)
  (cond ((= bit 0) (left-branch branch))
        ((= bit 1) (right-branch branch))
        (else (error "bad bit: CHOOSE-BRANCH" bit))))

(define (adjoin-set x set)
  (cond ((null? set) (list x))
        ((< (weight x) (weight (car set))) (cons x set))
        (else (cons (car set)
                    (adjoin-set x (cdr set))))))

(define (make-leaf-set pairs)
  (if (null? pairs)
      '()
      (let ((pair (car pairs)))
        (adjoin-set (make-leaf (car pair)   ; symbol
                               (cadr pair)) ; frequency
                    (make-leaf-set (cdr pairs))))))

(define (generate-huffman-tree pairs)
  (successive-merge (make-leaf-set pairs)))

(define (successive-merge tree-set)
  (if (null? (cdr tree-set)) ; (= (length tree-list) 1)
      (car tree-set)
      (let ((tree1 (car tree-set))
            (tree2 (cadr tree-set)))
        (successive-merge (adjoin-set (make-code-tree tree1 tree2)
                                      (cddr tree-set))))))

; the encode functionality from 2.68
(define (encode message tree)
  (if (null? message)
      '()
      (append (encode-symbol (car message) tree)
              (encode (cdr message) tree))))

(define (encode-symbol symbol tree)
  (cond ((not (member-set symbol (symbols tree)))
         (error "encode-symbol: no seq for the symbol in tree" symbol tree))
        ((leaf? tree)
         '())
        ((member-set symbol (symbols (left-branch tree)))
         (cons 0 (encode-symbol symbol (left-branch tree))))
        ((member-set symbol (symbols (right-branch tree)))
         (cons 1 (encode-symbol symbol (right-branch tree))))))

(define member-set member)
; since a set is represented as a list, we can simply use the member procedure

; actual exercise 2.70

(define sample-tree
  (generate-huffman-tree '((a 2)
                           (get 2)
                           (sha 3)
                           (wah 1)
                           (boom 1)
                           (job 2)
                           (na 16)
                           (yip 9))))

(define sample-message
  '(get a job
	sha na na na na na na na na
        get a job
	sha na na na na na na na na
        wah yip yip yip yip yip yip yip yip yip
        sha boom))

; (length (encode sample-message sample-tree)) -> 84
; if we used a fixed length code, it would have to have length of >=3
; since there are 36 words here, the answer would be 108